A list of all commands used in the tutorial. See the video for more info
and please, don't use all of these at once - it will be chaos.
You have been warned.


this AddAction ["Repair vehicle","fixVehicle.sqf"];

this addAction ["Normal action","action.sqf"];

this addAction ["Code action",{hint "Code action working!"}];

this addAction ["Code-string action","hint ""Code-string action working!"""];

myActionVariable = "My action variable";
this addAction [myActionVariable,{hint format ["%1 action working!",myActionVariable]}];

this addAction ["<t color=""#33CCFF"">Colored action</t>",{hint "Colored action working!"}];

player addAction ["Draw something on map",{}];

this addAction ["Parameters action","paramAction.sqf",[name player, position player]];

this addAction ["Full syntax action",{hint "Full syntax action working!"},nil,1,true, true, "", "true", 10, false];

this addAction ["Remove this action!",{(_this select 0) removeAction (_this select 2);hint "Action successfully removed"}];

this addAction ["RemoveAction through script","removal.sqf"];


player removeaction 0;

removeallactions player;


//where mySoldier is stopped using stop command
this addAction ["Send me away!",{mySoldier stop false;(_this select 0) removeaction (_this select 2)}];


this AddAction ["Add actions to player",{
	player addAction ["First action",{}];
	mySecAct = player addAction ["Second action",{}];
	myTrdAct = player addAction ["Third action",{}];
	rem1 = player addAction ["Remove actions",{
		removeallactions player}
	];
	rem2 = player addAction ["Remove actions 2-3",{
		player removeAction mySecAct;
		player removeaction myTrdAct;}
	];
	player addAction ["Remove other remove actions",{
		{player removeAction _x} forEach [rem1,rem2]}
	];
}];



this addAction [
	"Add a task",{myCustomActionActivation = true;
	(_this select 0) removeaction (_this select 2)}
];
//where a trigger has: myCustomActionActivation in the Condition box



Trigger setup:
Activated by: Anybody Present
Repeatable
Condition:
this && player inArea thisTrigger

On Activation:
myCountingAction = player addAction [
"Count n. of units in the area",
{
	_nOfObjects = count (_this select 3);
	hint format [
		"There are currently %1 units in the trigger area.",
		_nOfObjects
	];
	(_this select 0) removeaction (_this select 2)
},
thislist];

On Deactivation:
player removeaction myCountingAction;



action.sqf contents:

hint "Normal action working!";



paramAction.sqf contents:


_assignedObject = _this select 0;
_caller = _this select 1;
_ID = _this select 2;
_customArguments = _this select 3;


//or -> (_this select 3) select 0;
_myCustomPlayerName = _customArguments select 0;
_myCustomPlayerPosition = _customArguments select 1;

hint format ["Player named %1\n is currently located at\n%2",
_myCustomPlayerName, _myCustomPlayerPosition];




removal.sqf contents:


_assignedObject = _this select 0;
_ID = _this select 2;

/*
.
.
.
normal script, do some fancy stuff here
.
.
.
*/

hint "Action successfully removed";
_assignedObject removeAction _ID;